#
#From: "Mark" <gci.net!bearcub@gendex.com>
#Date: Fri, 31 Jul 1998 17:13:17 -0800
#I hacked a template that includes both the family group sheet and linked
#pedigree charts for husband and wife if you want to put it in your template
#directory. I couldn't see any options to do that, so I brute forced it with
#the output template, the g2h code is pretty ugly, but it appears to work for
#me.

#
# GED2HTML output program -- customize to taste
#
# Copyright (c) 1998 Eugene W. Stark
# All rights reserved.
#
# Permission is hereby granted to registered users of GED2HTML to
# make copies and modifications to this code for their own personal
# use and to distribute such modified copies, provided that this
# copyright notice is retained on all modified or distributed copies.
# Any other use of this code is prohibited without written permission.
#

#---------------------------------------------------------------------
# The first several definitions in this file are entry points that
# the output processor expects to be here.  Whatever changes you make,
# you must leave some sort of definitions here for these routines.
#---------------------------------------------------------------------

define do_initialize		{ do_initialize_    ; }
define do_index       i		{ do_index_       i ; }
define do_surnames    s		{ do_surnames_    s ; }
define do_individuals i		{ do_individuals_ i ; }
define do_families    f		{ do_families_    f ; }
define do_sources     s		{ do_sources_     s ; }
define do_notes       n		{ do_notes_       n ; }
define do_gendex      i		{ do_gendex_	  i ; }

#---------------------------------------------------------------------
# The rest are auxiliary routines used by the above.
# You can change whatever you want from this point on.
#---------------------------------------------------------------------

#---------------------------------------------------------------------
# INITIALIZATION
#---------------------------------------------------------------------

# This routine runs *after* the initialization routine from an options
# file specified in the dialog box or command line, and *before* any
# GEDCOM is read.

define do_initialize_
local l
{
  internationalize ;
  #
  # The purpose of the following silliness is to get an English-formatted
  # date to put in the META elements of the HTML output, without
  # affecting the previously selected language and locale.
  #
  set l to LANGUAGE
  set LANGUAGE to "English"
  set METADATE to TODAY
  set LANGUAGE to l
}

#---------------------------------------------------------------------
# PAGE HEADERS AND FOOTERS
#---------------------------------------------------------------------

# Output the HTML BODY tag, handling colors, images, etc.

define html_body
{
  print "<BODY" ,
  if BACKGROUND_COLOR then
    print " BGCOLOR=\"" BACKGROUND_COLOR "\"" ,
  end
  if BACKGROUND_IMAGE then
    print " BACKGROUND=\"" BACKGROUND_IMAGE "\"" ,
  end
  if TEXT_COLOR then
    print " TEXT=\"" TEXT_COLOR "\"" ,
  end
  if LINK_COLOR then
    print " LINK=\"" LINK_COLOR "\"" ,
  end
  if VISITED_COLOR then
    print " VLINK=\"" VISITED_COLOR "\"" ,
  end
  print ">" ;
}

# Produce the footer on each HTML page.

define page_footer
{
   if HOMEPAGE then
      print "<P><A HREF=\"" HOMEPAGE "\">" ,
      print_alternatives HOME_TEXT "HOME" ;
      print "</A></P>" ;
   else
      print "<P></P>" ;
   end
   print "<HR>" ;
   print "<EM>" ,
   print_alternatives CREATED_BY_TEXT "HTML created by" ;
   print " <A HREF=\"http://www.gendex.com/ged2html/\">" VERSION "</A> " ,
   print_alternatives ON_TEXT "on" ;
   print " " TODAY "</EM>.  " ;
   print "<HR>" ;
}

# Output author contact information, if MAILTO is set

define author_contact
{
  if MAILTO then
    print "<P><A HREF=\"mailto:" MAILTO "\">" ,
    print_alternatives EMAIL_TEXT "EMAIL" ;
    print "</A>" ;
    print "<HR></P>" ;
  else
    print "<HR>" ;
  end
}

# Output the first argument if it is non-NULL, otherwise the second argument.
# This is used for international customization.

define print_alternatives x y
{
  if x then
    print x ,
  else
    print y ,
  end
}

#---------------------------------------------------------------------
# PERSONS INDEX PAGES
#---------------------------------------------------------------------

# Output a single page of the hierarchical persons index.
#   Parameter i is head of a list of index nodes to be output
#   on a single page.

define do_index_ i
{
  print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2//EN\">" ;
  print "<HTML>" ;
  print "<HEAD>" ;
  print "<TITLE>" ,
  print "(" ,
  print_name i.parent.first.name ;
  print " - " ,
  print_name i.parent.last.name ;
  print ")" ,
  print "</TITLE>" ;
  if ~OMIT_META then
    print "<META NAME=\"Description\" content=\"",
    print_alternatives INDEX_OF_PERSONS_TEXT "Index of Persons" ;
    print_alternatives COLON_TEXT ": " ;
    print_name i.parent.first.name ;
    print " - " ,
    print_name i.parent.last.name ".  " ;
    header_info ;
    print "\">" ;
    print "<META NAME=\"Keywords\" content=\"" ,
    print_alternatives INDEX_OF_PERSONS_TEXT "Index of Persons" ;
    print ", GED2HTML, genealogy\">" ;
    print "<META NAME=\"Generator\" content=\"" VERSION "\">" ;
    print "<META NAME=\"Date\" content=\"" METADATE "\">" ;
    if HEADER.copr then
      print "<META NAME=\"Copyright\" content=\"" HEADER.copr "\">" ;
    end
  end
  print "</HEAD>" ;
  html_body ;
  print "<H2>" ,
  print_alternatives INDEX_OF_PERSONS_TEXT "Index of Persons" ;
  print "</H2>" ;
  if ~(i.parent & i.parent.parent) then
    print "<EM>" ,
    header_info ;
    if HEADER.copr then
      print "<BR>" HEADER.copr ;
    end
    print "</EM>" ;
    if HEADER.note then
      print "<P>" ;
      print_text HEADER.note 0 ;
      print "</P>" ;
    end
    if HEADER.submitter then
      submitter_info HEADER.submitter ;
    end
    author_contact ;
  end
  print "<P>" ;
  while i do
    if i.children then
      #
      # If there are still-lower-level index nodes,
      # output links to them.
      #
      print "<A HREF=\"" i.url "\">" ,
      print_name i.first.name ;
      if i.first.title then
         print " (" i.first.title ")" ,
      end
      print " -- to -- " ,
      print_name i.last.name ;
      if i.last.title then
         print " (" i.last.title ")" ,
      end
      print "</A><BR>" ;
    else
      #
      # If we have reached a leaf node of the index,
      # output a link to the corresponding individual data page.
      #
      print "<A NAME=\"" i.first.xref "\"></A>" ;
      print "<A HREF=\"" ,
      indiv_url i.first ;
      print "\">" ,
      print_name i.first.name ;
      if i.first.living then
         print "</A>" ,
      else
         if i.first.title then
           print " (" i.first.title ")" ,
         end
         print "</A>" ,
         print " (" ,
	 birth_and_death i.first ;
         print ")" ,
      end
      print "<BR>" ;
    end
    if ~i.next then
      print "</P>" ;
      index_links i.parent 0 ;
    end
    set i to i.next
  end
  print "<P><A HREF=\"" SURNAMES_URL "\">" ,
  print_alternatives SURNAMES_TEXT "SURNAMES" ;
  print "</A></P>" ;
  page_footer ;
  print "</BODY>" ;
  print "</HTML>" ;
}

#
# Create UP, BACK, and NEXT pointers for navigation within a
# hierarchical index.
# The second argument is zero for persons index, nonzero for
# surnames index
#

define index_links i which
local pred succ
{
  print "<P>" ;
  if i then
    if i.parent then
      if UP_TEXT then
        index_link UP_TEXT i.parent which ;
      else
        index_link "UP" i.parent which ;
      end
    end
    if i.prev then
      if BACK_TEXT then
        index_link BACK_TEXT i.prev which ;
      else
        index_link "BACK" i.prev which ;
      end
    else
      set pred to i.pred
      if pred then
        if BACK_TEXT then
          index_link BACK_TEXT i.parent.pred which ;
        else
          index_link "BACK" i.parent.pred which ;
        end
      end
    end
    if i.next then
      if NEXT_TEXT then
        index_link NEXT_TEXT i.next which ;
      else
        index_link "NEXT" i.next which ;
      end
    else
      set succ to i.succ
      if succ then
        if NEXT_TEXT then
          index_link NEXT_TEXT i.succ which ;
        else
          index_link "NEXT" i.succ which ;
        end
      end
    end
  end
  print "</P>" ;
}

# Output a link to a node i in the persons index,
#   with d as the highlighted text of the link.
# The third argument is zero for persons index, nonzero for
# surnames index

define index_link d s which
{
  print "<A HREF=\"" s.url "\">" d "</A>" ,
  print " (" ,
  if which then
    emit_surname s.first.surname ;
    print " - " ,
    emit_surname s.last.surname ;
  else
    print_name s.first.name ;
    print " - " ,
    print_name s.last.name ;
  end
  print ")<BR>" ;
}

# Routine that outputs information from the GEDCOM header on
# each index page.

define header_info
{
  print NUMBER_OF_INDIVIDUALS " " ,
  print_alternatives INDIVIDUALS_TEXT "individuals" ;
  print ", " NUMBER_OF_FAMILIES " " ,
  print_alternatives FAMILIES_TEXT "families" ;
  if HEADER.filename then
     print " " ,
     print_alternatives FROM_FILE_TEXT "from file" ;
     print " " HEADER.filename ,
     if HEADER.date then
         print " (" HEADER.date.value ")" ;
     end
  end
}

# Output submitter information from the GEDCOM header

define submitter_info s
local t
{
  if s.name | s.address | s.phone then
    print "<P><B>" ,
    print_alternatives AUTHOR_TEXT "Author" ;
    print_alternatives COLON_TEXT ": " ;
    print "</B><BR>" ,
    if s.name & s.name.text then
      print s.name.text ,
      print "<BR>" ;
    end
    if s.address & s.address.text then
      set t to s.address.text
      while t do
        print t.text ,
        if t.cont then
          print ", " ,
	  set t to t.cont
	else
	  set t to t.conc
	end
       end
       print "<BR>" ;
    end
    if s.phone & s.phone.text then
      print s.phone.text ;
    end
    print "</P>" ;
  end
}

#---------------------------------------------------------------------
# SURNAMES INDEX PAGES
#---------------------------------------------------------------------

# Output a single page of the surnames index.
#   Parameter s is the head of a list of surname index nodes to
#   be output in a single file.

define do_surnames_ s
local pred succ tabs
{
  print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2//EN\">" ;
  print "<HTML>" ;
  print "<HEAD>" ;
  print "<TITLE>" ,
  print_alternatives INDEX_OF_SURNAMES_TEXT "Index of Surnames" ;
  print "</TITLE>" ;
  if ~OMIT_META then
    print "<META NAME=\"Description\" content=\"" ,
    print_alternatives INDEX_OF_SURNAMES_TEXT "Index of Surnames" ;
    print_alternatives COLON_TEXT ": " ;
    header_info ;
    print "\">" ;
    print "<META NAME=\"Keywords\" content=\"Surnames, Index, GED2HTML, genealogy\">" ;
    print "<META NAME=\"Generator\" content=\"" VERSION "\">" ;
    print "<META NAME=\"Date\" content=\"" METADATE "\">" ;
    if HEADER.copr then
      print "<META NAME=\"Copyright\" content=\"" HEADER.copr "\">" ;
    end
  end
  print "</HEAD>" ;
  html_body ;
  print "<H2>" ,
  print_alternatives INDEX_OF_SURNAMES_TEXT "Index of Surnames" ;
  print "</H2>" ;
  if ~(s.parent & s.parent.parent) then
    print "<EM>" ,
    header_info ;
    if HEADER.copr then
      print "<BR>" HEADER.copr ;
    end
    print "</EM>" ;
    if HEADER.note then
      print "<P>" ;
      print_text HEADER.note 0 ;
      print "</P>" ;
    end
    if HEADER.submitter then
      submitter_info HEADER.submitter ;
    end
    author_contact ;
  end
  #
  # If the index consists of a single node, and we haven't been
  # asked to produce a hierarchical index, then use "alphabet tab" format
  #
  if ~s.children & SURNAME_WIDTH = 0 & ~NO_ALPHABET_TABS then
    do_alphabetical s ;
  #
  # Otherwise use the more general hierarchical format
  #
  else
    print "<P>" ;
    while s do
      if s.children then		# Internal node of hierarchical index
					# emit index tabs to lower levels
        print "<A HREF=\"" s.url "\">" ;
        emit_surname s.first.surname ;
        print "  -- to -- " ,
        emit_surname s.last.surname ;
        print "</A><BR>" ;
      else				# Leaf node of hierarchical index
					# emit links to persons index
        print "<A HREF=\"" s.index.url "#" s.first.xref "\">" ,
        emit_surname s.first.surname ;
        print "</A>" ,
        if s.next then
          print "," ;
        else
          print ;
        end
      end
      if ~s.next then
        print "</P>" ;
        index_links s.parent 1 ;
      end
      set s to s.next
    end
  end
  print "<P><A HREF=\"" PERSONS_URL "\">" ,
  print_alternatives INDEX_TEXT "INDEX" ;
  print "</A></P>" ;
  page_footer ;
  print "</BODY>" ;
  print "</HTML>" ;
}

# Produce an "alphabet tab" style surnames index page.

define do_alphabetical s
local tabs l n
{
   set tabs to "A B C D E F G H I J K L M N O P Q R S T U V W X Y Z"
   print "<H3>" ;
   for l in tabs do
     print "<A HREF=\"#" l "\">" l "</A>" ;
   end
   print "</H3>" ;
   for l in tabs do
     if s & s.first then
       print "<P>" ;
       while s & s.first & (s.first.surname <= l) do
          print "<A HREF=\"" s.index.url "#" s.first.xref "\">" ,
          emit_surname s.first.surname ;
          print "</A>" ,
          set n to s.succ
          if n & n.first.surname then
            if n.first.surname <= l then
              print "," ;
            else
              print "<BR>" ;
            end
          else
            print ;
          end
          set s to n
       end
       print "</P>" ;
     end
     print "<A NAME=\"" l "\"></A>" ;
   end
   if s then
     print "<P>" ;
     while s do
        print "<A HREF=\"" s.index.url "#" s.first.xref "\">" ,
        emit_surname s.first.surname ;
        print "</A>" ,
        set n to s.succ
        if n then
          print "," ;
        else
          print ;
        end
        set s to n
     end
     print "</P>" ;
   end
}

# Routine for outputting a link to a node s in the surnames index,
# with d as the highlighted text of the link.

define surname_link d s
{
  print "<A HREF=\"" s.url "\">" d "</A>" ,
  print " (" ,
  emit_surname s.first.surname ;
  print " - " ,
  emit_surname s.last.surname ;
  print "</A>)<BR>" ;
}

# Routine for outputting either ??? or a surname.

define emit_surname s
{
   if s then
     print s ,
   else
     print "???" ,
   end
}

#---------------------------------------------------------------------
# INDIVIDUALS PAGES
#---------------------------------------------------------------------

# Output a page of individuals.
#   Parameter i is head of a list of individuals to be output
#   in a single page.

define do_individuals_ i
local ii ok
{
  # If we are doing family group sheet output, then we only output
  # something if there is an individual in the list who doesn't belong
  # to any family group.  So, scan for this first.

  set ok to 0
  set ii to i
  if FAMILY_GROUPS then
    while ii & ~ok do
      if ~ii.families & ~ii.marriages then
        set ok to 1
      end
      set ii to ii.next
    end
  else
    set ok to 1
  end
  if ok then
    print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2//EN\">" ;
    print "<HTML>" ;
    print "<HEAD>" ;
    print "<TITLE>" ,
    print i.xref ": " ,
    print_name i.name ;
    if i.title then
      print " (" i.title ")" ;
    end
    if ~i.living then
      print " (" ,
      birth_and_death i ;
      print ")" ;
    end
    print "</TITLE>" ;
    if ~OMIT_META then
      print "<META NAME=\"Description\" content=\"" ,
      if i.title then
        print i.title ;
      end
      print_name i.name ;
      if ~i.living then
        print " (" ,
        birth_and_death i ;
        print ")" ,
      end
      print "\">" ;
      print "<META NAME=\"Keywords\" content=\"",
      print_name i.name ;
      print ", GED2HTML, genealogy\">" ;
      print "<META NAME=\"Generator\" content=\"" VERSION "\">" ;
      print "<META NAME=\"Date\" content=\"" METADATE "\">" ;
    end
    print "</HEAD>" ;
    html_body ;
    while i do
      # If we are doing family-group-style output, then only output
      # an individual if they don't have any family.
      if ~FAMILY_GROUPS | (~i.families & ~i.marriages) then
        if i.living then
          do_living i ;
        else
          do_individual i ;
        end
      end
      set i to i.next
    end
    print "</BODY>" ;
    print "</HTML>" ;
  end
}

# Routine for outputting the data on an individual page for which
# the individual is flagged as "living".

define do_living i
{
  print "<H2><A NAME=\"" i.xref "\">" ,
  print_name i.name ;
  print "</A></H2>" ;
  do_note i.living 1 ;
  print "<P><A HREF=\"" PERSONS_URL "\">" ;
  print_alternatives INDEX_TEXT "INDEX" ;
  print "</A></P>" ;
}

# Routine for outputting the data on an individual page for which
# the individual is not flagged as "living".

define do_individual i
local br fn s e a r f c n o
{
  print "<H2><A NAME=\"" i.xref "\"></A>" ,
  include i.xref ^ ".img"
  print_name i.name ;
  if i.title then
    print " (" i.title ")" ,
  end
  print "</H2>" ;
  indiv_notes i 0 ;
  indiv_sources i 0 ;
  print "<H3>" ,
  birth_and_death i;
  print "</H3>" ;
  if i.events | i.attributes | (i.names & i.names.next) | i.rfn
	| i.afn | i.refns | i.rin | i.ordinances then
    print "<UL>" ;
    if i.names & i.names.next then
      for n in i.names.next do
        do_name n 1 ;
      end
    end
    if i.attributes then
      for a in i.attributes do
	do_attr a 1 ;
      end
    end
    if i.events then
      for e in i.events do
        do_event e 1 ;
      end
    end
    if i.ordinances then
      for o in i.ordinances do
        do_ordn o 1 ;
      end
    end
    if i.rfn then
      do_attr i.rfn 1 ;
    end
    if i.afn then
      do_attr i.afn 1 ;
    end
    if i.refns then
      for r in i.refns do
        do_refn r 1 ;
      end
    end
    if i.rin then
      do_attr i.rin 1 ;
    end
    print "</UL>" ;
  end
  set br to 0
  if i.father then
    set br to 1
    print "<B>" ,
    print_alternatives FATHER_TEXT "Father" ;
    print_alternatives COLON_TEXT ": " ;
    print "</B> <A HREF=\"" i.father.url "\">" ,
    print_name i.father.name ;
    print "</A><BR>" ;
  end
  if i.mother then
    set br to 1
    print "<B>" ,
    print_alternatives MOTHER_TEXT "Mother" ;
    print_alternatives COLON_TEXT ": " ;
    print "</B> <A HREF=\"" i.mother.url "\">" ,
    print_name i.mother.name ;
    print "</A><BR>" ;
  end
  if br then
    print "<BR>" ;
  end
  set fn to 1
  for f in i.marriages do
    print "<B>" ,
    print_alternatives FAMILY_TEXT "Family" ;
    print " " fn "</B>" ;
    print_alternatives COLON_TEXT ": " ;
    if i.ismale & f.wife then
        print "<A HREF=\"" f.wife.url "\">" ,
        print_name f.wife.name ;
        print "</A>" ;
    end
    if i.isfemale & f.husband then
        print "<A HREF=\"" f.husband.url "\">" ,
        print_name f.husband.name ;
        print "</A>" ;
    end
    if f.events | f.ordinances | f.refns | f.rin then
      print "<UL>" ;
      if f.events then
        for e in f.events do
          do_event e 1 ;
        end
      end
      if f.ordinances then
        for o in f.ordinances do
          do_ordn o 1 ;
        end
      end
      if f.refns then
        for r in f.refns do
          do_refn r 1 ;
        end
      end
      if f.rin then
        do_attr f.rin 1 ;
      end
      print "</UL>" ;
    end
    if f.children then
      print "<OL>" ;
      for c in f.children do
	print "<LI> " ,
	child_had_issue c ;
        print "<A HREF=\"" c.url "\">" ,
        print_name c.name ;
        print "</A>" ;
      end
      print "</OL>" ;
    else
      print "<BR>" ;
    end
    set fn to fn+1
  end
  print "<HR>" ;
  print "<HR>" ;
  print "<P><A HREF=\"" PERSONS_URL "\">" ,
  print_alternatives INDEX_TEXT "INDEX" ;
  print "</A></P>" ;
  #
  # Emit all notes and sources associated with this individual
  # and all associated families, unless they were already output
  # previously.
  #
  if ~INLINE_NOTES then
    indiv_notes i 1 ;
    for f in i.marriages do
      family_notes f 1 ;
    end
  end
  if ~INLINE_SOURCES then
    indiv_sources i 1 ;
    for f in i.marriages do
      family_sources f 1 ;
    end
  end
  include i.xref ^ ".inc"
  page_footer ;
}

# Output birth and death information for an individual.

define birth_and_death i
{
  if i.birth | i.death then
    if i.birth & i.birth.date then
      print i.birth.date.value  ,
    else
      print "____" ,
    end
    print " - " ,
    if i.death & i.death.date then
      print i.death.date.value ,
    else
      print "____" ,
    end
  else
    print "____ - ____" ,
  end
}

# Routine for outputting a name structure
# If "item" is nonzero, then an HTML <LI> is output,
# together with the GEDCOM tag associated with the attribute.

define do_name n item
local s
{
  if item then
    print "<LI><EM>" n.tagname.upper "</EM>: " ,
  end
  if n.fullname then
    print n.fullname ;
  end
  if n.sources then
    for s in n.sources do
       do_citation s INLINE_SOURCES ;
    end
  end
  if n.notes then
    for s in n.notes do
       do_note s INLINE_NOTES ;
    end
  end
}

# Routine for outputting the full text of a name,
# if the name is non-null, and do nothing otherwise.

define print_name n
{
  if n then
    print n.fullname ,
  end
}

# Routine to output an indication of whether family line continues
# with a given individual

define child_had_issue c
local s f
{
  set s to "&nbsp;"
  for f in c.marriages do
    if f.children then
      set s to "+"
    end
  end
  print "<TT>" s "</TT>" ,
}

# Emit the proper URL to take us to the page that has the data
# for a given individual.
#
# If we aren't producing family group sheets, then just link to
# the URL for the individual.
# If we are producing family group sheets, then link to the most
# appropriate family page:
#	If the individual has a marriage, then the link goes to that
#	  family's page.
#	If the individual has no marriage, then the link goes to the first
#	  family in which the individual is listed as a child.
#	If the individual is not a child in any family, then the link goes
#	  to the page for that individual.

define indiv_url i
local m
{
  if FAMILY_GROUPS then
    if i.marriages then
      set m to i.marriages
      if m then
         print m.url "#" i.xref ,
      end
    else
      set m to i.families
      if m then
        print m.url "#" i.xref ,
      else
        print i.url ,
      end
    end
  else
    print i.url ,
  end
}

#---------------------------------------------------------------------
# FAMILY GROUP PAGES
#---------------------------------------------------------------------

# Output a page of families.
#   Parameter f is head of a list of families to be output
#   in a single page.

define do_families_ f
{
  # If we are not doing family-group-style output, then do nothing
  if FAMILY_GROUPS then
    print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2//EN\">" ;
    print "<HTML>" ;
    print "<HEAD>" ;
    print "<TITLE>" ,
    if f.husband then
      print_name f.husband.name ;
    else
      print "(Unknown)" ,
    end
    print " / " ,
    if f.wife then
      print_name f.wife.name ;
    else
      print "(Unknown)" ,
    end
    print "</TITLE>" ;
    if ~OMIT_META then
      print "<META NAME=\"Keywords\" content=\"",
      if f.husband then
        print_name f.husband.name ;
        print ", " ,
      end
      if f.wife then
        print_name f.wife.name ;
        print ", " ,
      end
      print ", GED2HTML, genealogy\">" ;
      print "<META NAME=\"Generator\" content=\"" VERSION "\">" ;
      print "<META NAME=\"Date\" content=\"" METADATE "\">" ;
    end  
    print "</HEAD>" ;
    print "<BODY>" ;
    while f do
      do_family f ;
      set f to f.next
    end
    print "</BODY>" ;
    print "</HTML>" ;
  end
}

# Routines to output a family group sheet for a given family

define do_family f
local e m c n
{
  print "<H2 ALIGN=CENTER>" ,
  if f.husband then
    print "<A NAME=\"" f.husband.xref "\">" ,
    print_name f.husband.name ;
    print "</A>" ,
  else
    print "(Unknown)" ,
  end
  print " / " ,
  if f.wife then
    print "<A NAME=\"" f.wife.xref "\">" ,
    print_name f.wife.name ;
    print "</A>" ,
  else
    print "(Unknown)" ,
  end
  print "</H2>" ;
  if f.notes then
    for n in f.notes do
      do_note n INLINE_NOTES ;
    end
  end
  print "<TABLE CELLSPACING=0 WIDTH=\"100%\">" ;
  print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=3>" ;
  if f.husband then  
    print "<TR><TD COLSPAN=4>" ,
    print_alternatives HUSBAND_TEXT "Husband" ;
    print_alternatives COLON_TEXT ": " ;
    print "<B>" ,
    print_name f.husband.name ;
    print "</B>" ;
    print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=3>" ;
    do_husband_or_wife f f.husband "Husband" ;
    print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=3>" ;
  else
    print "<TR><TD COLSPAN=4>" ,
    print_alternatives HUSBAND_TEXT "Husband" ;
    print_alternatives COLON_TEXT ": " ;
    print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=3>" ;
  end
  if f.wife then
    print "<TR><TD COLSPAN=4>" ,
    print_alternatives WIFE_TEXT "Wife" ;
    print_alternatives COLON_TEXT ": " ;
    print "<B>" ,
    print_name f.wife.name ;
    print "</B>" ;
    print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=3>" ;
    do_husband_or_wife f f.wife "Wife" ;
    print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=3>" ;
  else
    print "<TR><TD COLSPAN=4>" ,
    print_alternatives WIFE_TEXT "Wife" ;
    print_alternatives COLON_TEXT ": " ;
    print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=3>" ;
  end
  print "<TR><TD COLSPAN=4><B>" ,
  print_alternatives CHILDREN_TEXT "CHILDREN" ;
  print "</B>" ;
  print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=1>" ;
  for c in f.children do
    do_child f c ;
  end
  print "</TABLE>" ;

#################################################### 
#################################################### 
#
# Mark's Additions are here
#
#################################################### 
#################################################### 

print "</BR>";

if f.husband then
 print_alternatives HUSBAND_TEXT "Pedigree Chart for" ;
 print_alternatives COLON_TEXT ": " ;
 print "<B>" ,
 print_name f.husband.name ;
 print "</B>" ;
 pedigree_out f.husband ;
 print "</BR>";
end
if f.wife then
 print_alternatives WIFE_TEXT "Pedigree Chart for" ;
 print_alternatives COLON_TEXT ": " ;
 print "<B>" ,
 print_name f.wife.name ;
 print "</B>" ;
 pedigree_out f.wife;
 print "</BR>";
end

#################################################### 
#################################################### 

  print "<P><A HREF=\"" PERSONS_URL "\">" ,
  print_alternatives INDEX_TEXT "INDEX" ;
  print "</A></P>" ;
  #
  # Emit all notes and sources associated with this individual
  # unless they were already output previously.
  #
  if ~INLINE_NOTES then
    family_notes f 1 ;
    if f.husband then
      indiv_notes f.husband 1 ;
    end
    if f.wife then
      indiv_notes f.wife 1 ;
    end
    if f.children then
      for c in f.children do
        indiv_notes c 1 ;
      end
    end
  end
  if ~INLINE_SOURCES then
    family_sources f 1 ;
    if f.husband then
      indiv_sources f.husband 1 ;
    end
    if f.wife then
      indiv_sources f.wife 1 ;
    end
    if f.children then
      for c in f.children do
        indiv_sources c 1 ;
      end
    end
  end
  page_footer ;
}

define do_child f c
{
  print "<TR VALIGN=TOP>" ,
  print "<TD ALIGN=RIGHT>" ,
  print_alternatives NAME_TEXT "Name" ;
  print_alternatives COLON_TEXT ": " ;
  print "<TD>" ,
  print "<A NAME=\"" c.xref "\"></A>" ;
  print "<A HREF=\"" ,
  indiv_url c ;
  print "\">" ,
  print_name c.name ;
  print "</A>" ;
  if ~c.living then
    indiv_notes c INLINE_NOTES ;
    indiv_sources c INLINE_SOURCES ;
  else
    do_note c.living INLINE_NOTES ;
  end
  print "<TR VALIGN=TOP>" ,
  born_field c ;
  if c.marriages then
     married_field f c.marriages ;
  end
  died_field c ;
  spouses_field c ;
  print "<TR><TD COLSPAN=4><HR NOSHADE SIZE=1>" ;
}

define do_husband_or_wife f i which
local e m c n s
{
  if i & (~i.living) then
    born_field i ;
    if which = "Husband" then
      married_field f i ;
    end
    died_field i ;
    father_field i ;
    mother_field i ;
    if i.notes then
      print "<TR VALIGN=TOP><TD ALIGN=RIGHT>" ,
      print_alternatives NOTES_TEXT "Notes" ;
      print_alternatives COLON_TEXT ": " ;
      print "<TD COLSPAN=3>" ;
      indiv_notes i INLINE_NOTES ;
    end
    if i.sources then
      print "<TR VALIGN=TOP><TD ALIGN=RIGHT>" ,
      print_alternatives SOURCES_TEXT "Sources" ;
      print_alternatives COLON_TEXT ": " ;
      print "<TD COLSPAN=3>" ;
      indiv_sources i INLINE_SOURCES ;
    end
  else
    print "<TR VALIGN=TOP><TD ALIGN=RIGHT WIDTH=\"10%\">Born:<TD WIDTH=\"40%\">" ,
    print "<TD ALIGN=RIGHT WIDTH=\"10%\">at:<TD WIDTH=\"40%\">" ;
    print "<TD ALIGN=RIGHT>at:<TD>" ;
    print "<TR VALIGN=TOP><TD ALIGN=RIGHT>Died:<TD>" ,
    print "<TD ALIGN=RIGHT>at:<TD>" ;
    print "<TR VALIGN=TOP><TD ALIGN=RIGHT>" ,
    print_alternatives FATHER_TEXT "Father" ;
    print_alternatives COLON_TEXT ": " ;
    print "<TD>" ,
    print "<TR VALIGN=TOP><TD ALIGN=RIGHT>" ,
    print_alternatives MOTHER_TEXT "Mother" ;
    print_alternatives COLON_TEXT ": " ;
    print "<TD>" ,
  end
}

# Routines to do output of the various kinds of fields in the
# family group sheet.

define born_field i
{
   print "<TR VALIGN=TOP>" ,
   print "<TD ALIGN=RIGHT WIDTH=\"10%\">" ,
   print_alternatives BORN_TEXT "Born" ;
   print_alternatives COLON_TEXT ": " ;
   print "<TD WIDTH=\"30%\">" ,
   if i.birth & ~i.living then
     if i.birth.date then
       print i.birth.date.value ,
     end
     event_notes i.birth INLINE_NOTES ;
     event_sources i.birth INLINE_SOURCES ;
   end
   print "<TD ALIGN=RIGHT WIDTH=\"10%\">" ,
   print_alternatives AT_TEXT "at" ;
   print_alternatives COLON_TEXT ": " ;
   print "<TD WIDTH=\"40%\">" ,
   if i.birth & i.birth.place & ~i.living then
     print i.birth.place.name ;
   else
     print ;
   end
}

define died_field i
{
   print "<TR VALIGN=TOP>" ,
   print "<TD ALIGN=RIGHT>" ,
   print_alternatives DIED_TEXT "Died" ;
   print_alternatives COLON_TEXT ": " ;
   print "<TD>" ,
   if i.death & ~i.living then
     if i.death.date then
       print i.death.date.value ,
     end
     event_notes i.death INLINE_NOTES ;
     event_sources i.death INLINE_SOURCES ;
   end
   print "<TD ALIGN=RIGHT>" ,
   print_alternatives AT_TEXT "at" ;
   print_alternatives COLON_TEXT ": " ;
   print "<TD>" ,
   if i.death & i.death.place & ~i.living then
     print i.death.place.name ,
   else
     print ;
   end
}

define married_field f c
local m e
{
   set m to 0
   if ~c.living then
     for e in f.events do
       if e.tagcode = "MARR" then
         print "<TR VALIGN=TOP>" ,
         print "<TD ALIGN=RIGHT>" ,
         print_alternatives MARRIED_TEXT "Married" ;
         print_alternatives COLON_TEXT ": " ;
         print "<TD>" ,
         if e.date then
           print e.date.value ,
         end
         print "<TD ALIGN=RIGHT>" ,
         print_alternatives AT_TEXT "at" ;
         print_alternatives COLON_TEXT ": " ;
         print "<TD>" ,
	 if e.place then
	   print e.place.name ,
         end
	 print ;
         set m to 1
       end
     end
   end
   if m = 0 then
     print "<TR VALIGN=TOP>" ,
     print "<TD ALIGN=RIGHT>" ,
     print_alternatives MARRIED_TEXT "Married" ;
     print_alternatives COLON_TEXT ": " ;
     print "<TD>" ,
     print "<TD ALIGN=RIGHT>" ,
     print_alternatives AT_TEXT "at" ;
     print_alternatives COLON_TEXT ": " ;
     print "<TD>" ;
   end
}

define spouses_field c
local m first
{
   print "<TR VALIGN=TOP>" ,
   print "<TD ALIGN=RIGHT>" ,
   print_alternatives SPOUSES_TEXT "Spouses" ;
   print_alternatives COLON_TEXT ": " ;
   print "<TD COLSPAN=3>" ,   
   if ~c.living then
     set first to 1
     for m in c.marriages do
        if c.ismale & m.wife then
           if ~first then
             print ", " ,
           else
             set first to 0
           end
           print "<A HREF=\"" ,
           indiv_url m.wife ;
           print "\">" ,
           print_name m.wife.name ;
           print "</A>" ;
        elseif c.isfemale & m.husband then
           if ~first then
             print ", " ,
           else
             set first to 0
           end
           print "<A HREF=\"" ,
           indiv_url m.husband ;
           print "\">" ,
           print_name m.husband.name ;
           print "</A>" ;
        end
     end
   end
}

define father_field i
{
   print "<TR VALIGN=TOP>" ,
   print "<TD ALIGN=RIGHT>" ,
   print_alternatives FATHER_TEXT "Father" ;
   print_alternatives COLON_TEXT ": " ;
   print "<TD>" ,
   if i.father & ~i.living then
       print "<A HREF=\"" ,
       indiv_url i.father ;
       print "\">" ,
       print_name i.father.name ;
       print "</A>" ;
   else
       print ;
   end
}

define mother_field i
{
   print "<TR VALIGN=TOP>" ,
   print "<TD ALIGN=RIGHT>" ,
   print_alternatives MOTHER_TEXT "Mother" ;
   print_alternatives COLON_TEXT ": " ;
   print "<TD>" ,
   if i.mother & ~i.living then
       print "<A HREF=\"" ,
       indiv_url i.mother ;
       print "\">" ,
       print_name i.mother.name ;
       print "</A>" ;
   else
       print ;
   end
}


#---------------------------------------------------------------------
# LINKS TO NOTES AND SOURCES 
#---------------------------------------------------------------------

# Find all notes associated with a single family.
# If here is nonzero, then output the notes right now,
# otherwise output links to the notes.

define family_notes f here
local n c e
{
   if f.events then
     for e in f.events do
       event_notes e here ;
     end
   end
   if f.notes then
     for n in f.notes do
       do_note n here ;
     end
   end
}

# Find all notes associated with a single individual
# If here is nonzero, then output the notes right now,
# otherwise output links to the notes.

define indiv_notes i here
local n e a
{
  if i.living then
    do_note i.living here ;
  else
    if i.names then
      for n in i.names do
         name_notes n here ;
      end
    end
    if i.attributes then
      for a in i.attributes do
         if a.event then
           event_notes a.event here ;
         end
      end
    end
    if i.events then
      for e in i.events do
         event_notes e here ;
      end
    end
    if i.notes then
      for n in i.notes do
         do_note n here ;
      end
    end
  end
}

# Find all notes associated with a single event
# If here is nonzero, then output the notes right now,
# otherwise output links to the notes.

define event_notes e here
local n
{
  if e.notes then
    for n in e.notes do
       do_note n here ;
    end
  end
}

# Find all notes associated with a name
# If here is nonzero, then output the notes right now,
# otherwise output links to the notes.

define name_notes n here
local nn
{
  if n.notes then
    for nn in n.notes do
       do_note nn here ;
    end
  end
}

# Find all sources associated with a single family group
# If here is nonzero, then output the sources right now,
# otherwise output links to the sources.

define family_sources f here
local s c e
{
   if f.events then
     for e in f.events do
       event_sources e here ;
     end
   end
   if f.sources then
     for s in f.sources do
       do_citation s here ;
     end
   end
}

# Find all sources associated with a single individual
# If here is nonzero, then output the sources right now,
# otherwise output links to the sources.

define indiv_sources i here
local s e a n
{
  if ~i.living then
    if i.names then
      for n in i.names do
         name_sources n here ;
      end
    end
    if i.attributes then
      for a in i.attributes do
         if a.event then
           event_sources a.event here ;
         end
      end
    end
    if i.events then
      for e in i.events do
         event_sources e here ;
      end
    end
    if i.sources then
      for s in i.sources do
         do_citation s here ;
      end
    end
  end
}

# Output all sources associated with a single event
# If here is nonzero, then output the sources right now,
# otherwise output links to the sources.

define event_sources e here
local s
{
  if e.sources then
    for s in e.sources do
       do_citation s here ;
    end
  end
}

# Find all sources associated with a name
# If here is nonzero, then output the sources right now,
# otherwise output links to the sources.

define name_sources n here
local s
{
  if n.sources then
    for s in n.sources do
       do_citation s here ;
    end
  end
}



#---------------------------------------------------------------------
# SOURCES PAGES
#---------------------------------------------------------------------

# Output a page of surnames.
#   Parameter s is head of a list of sources to be output
#   in a single page.

define do_sources_ s
{
  print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2//EN\">" ;
  print "<HTML>" ;
  print "<HEAD>" ;
  print "<TITLE>" ,
  print_alternatives SOURCES_TEXT "Sources" ;
  print "</TITLE>" ;
  if ~OMIT_META then
    print "<META NAME=\"Description\" content=\"Sources\">" ;
    print "<META NAME=\"Keywords\" content=\"Sources, GED2HTML, genealogy\">" ;
    print "<META NAME=\"Generator\" content=\"" VERSION "\">" ;
    print "<META NAME=\"Date\" content=\"" METADATE "\">" ;
  end
  print "</HEAD>" ;
  html_body ;
  print "<H2>" ,
  print_alternatives SOURCES_TEXT "Sources" ;
  print "</H2>" ;
  while s do
    print "<P>" ;
    do_source s ;
    set s to s.next
  end
  page_footer ;
  print "</BODY>" ;
  print "</HTML>" ;
}

# Routine for outputting a SOUR structure

define do_source s
local n r
{
  if s.xref then
     print "<A NAME=\"" s.xref "\">[<B>" s.xref "</B>]</A>" ;
  else
     print "[<B>" s.tagname.upper "</B>]" ;
  end
  if s.abbreviation then
    print "<EM>" ;
    do_attr s.abbreviation 0 ;
    print "</EM>" ;
  end
  if s.title then
      print "<EM>" ;
      print_text s.title 0 ;
      print "</EM>" ;
  end
  if s.author | s.publication | s.refns | s.rin
	| s.change | s.repository
  then
    print "<UL>" ;
    if s.author then
      print_text s.author 1 ;
    end
    if s.publication then
      print_text s.publication 1 ;
    end
    if s.repository then
      do_repository s.repository 1 ;
    end
    if s.refns then
      for r in s.refns do
        do_refn r 1 ;
      end
    end
    if s.rin then
        do_attr s.rin 1 ;
    end
    if s.change then
      do_change s.change 1 ;
    end
    print "</UL>" ;
  end
  if s.text then
    print "<P><EM>" ;
    print_text s.text 0 ;
    print "</EM></P>" ;
  end
  if s.notes then
    for n in s.notes do
      do_note n 1 ;
    end
  end
}

# Routine for outputting a source citation

define do_citation c here
local n t
{
  if here then
    # Print the complete citation now, together with an anchor
    print "<P>" ;
    print "<A NAME=\"" c.serial "\">[<B>" c.serial "</B>]</A>" ;
    if c.source then
      print "<A HREF=\"" c.source.url "\">[" c.source.xref "]</A>" ;
      if c.source.abbreviation then
        print "<EM>" ;
        do_attr c.source.abbreviation 0 ;
        print "</EM>" ;
      end
    else
      print "[" c.tagname.upper "]" ;
    end
    print "</P>" ;
    if c.description then
      print_text c.description 0 ;
    end
    if c.page | c.event | c.quay | c.data | c.texts | c.notes then
      print "<UL>" ;
      if c.page then
        do_attr c.page 1 ;
      end
      if c.event then
        do_attr c.event 1 ;
      end
      if c.quay then
        do_attr c.quay 1 ;
      end
      if c.data then
        do_source_data c.data ;
      end
      if c.texts then
        for t in c.texts do
           print "<P><EM>" ;
           print_text t 0 ;
           print "</EM></P>" ;
        end
      end
      if c.notes then
        for n in c.notes do
          do_note n 1 ;
        end
      end
      print "</UL>" ;
    end
  else
    # Make a link to the citation on the same page
    print "<A HREF=\"#" c.serial "\">[" c.serial "]</A>" ;
  end
}

# Routine to output "source data", which is certain information that
# can appear in a source record or in a source citation

define do_source_data d
local e n t
{
  print "<LI><EM>" d.tagname.upper "</EM>: " ;
  if d.date | d.events | d.agency then
    print "<UL>" ;
    if d.date then
      print "<LI><EM>" d.date.tagname.upper "</EM>: " d.date.value ;
    end
    if d.events then
      for e in d.events do
        do_event e 1;
      end
    end
    if d.agency then
      do_attr d.agency 1 ;
    end
    print "</UL>" ;
  end
  if d.texts then
    for t in d.texts do
      print "<P><EM>" ;  
      print_text t 0 ;
      print "</EM></P>" ;
    end
  end
  if d.notes then
    for n in d.notes do
      do_note n 1 ;
    end
  end
}

# Routine for outputting source repository info
# First argument is a repository citation.
# If "item" is nonzero, then an HTML <LI> is output,
# together with the GEDCOM tag.

define do_repository r item
local rr rn n
{
  if item then
    print "<LI><EM>" r.tagname.upper "</EM>: " ,
  end
  set rr to r.repository
  if rr.name & rr.name.text then
    print rr.name.text ;
  end
  if rr.refns | rr.rin | r.caln | (rr.address & rr.address.text) then
    print "<UL>" ;
    if rr.refns then
       for rn in rr.refns do
         do_refn rn 1 ;
       end
    end
    if rr.rin then
       do_attr rr.rin 1 ;
    end
    if r.caln then
       do_attr r.caln 1 ;
    end
    if rr.address & rr.address.text then
       print_text rr.address.text 1 ;
    end
    print "</UL>" ;
  end
  if r.notes then
    for n in r.notes do
      do_note n 1 ;
    end
  end
  if rr.notes then
    for n in rr.notes do
      do_note n 1 ;
    end
  end
}

# Output change info.
#   If "item" is nonzero, then an HTML <LI> is output,
#   together with the GEDCOM tag.

define do_change c item
local n
{
  if item then
    print "<LI><EM>" c.tagname.upper "</EM>: " ,
  end
  if c.date then
    print c.date.value ;
  end
  if c.notes then
    for n in c.notes do
      do_note n 1 ;
    end
  end
}

#---------------------------------------------------------------------
# NOTES PAGES
#---------------------------------------------------------------------

# Output a page of notes.
#   Parameter n is head of a list of notes to be output
#   in a single page.

define do_notes_ n
{
  print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 3.2//EN\">" ;
  print "<HTML>" ;
  print "<HEAD>" ;
  print "<TITLE>" ,
  print_alternatives NOTES_TEXT "Notes" ;
  print "</TITLE>" ;
  if ~OMIT_META then
    print "<META NAME=\"Description\" content=\"" ,
    print_alternatives NOTES_TEXT "Notes" ;
    print "\">" ;
    print "<META NAME=\"Keywords\" content=\"Notes, GED2HTML, genealogy\">" ;
    print "<META NAME=\"Generator\" content=\"" VERSION "\">" ;
    print "<META NAME=\"Date\" content=\"" METADATE "\">" ;
  end
  print "</HEAD>" ;
  html_body ;
  print "<H2>" ,
  print_alternatives NOTES_TEXT "Notes" ;
  print "</H2>" ;
  while n do
    do_note n 2 ;
    set n to n.next
  end
  page_footer ;
  print "</BODY>" ;
  print "</HTML>" ;
}

# Routine for outputting a NOTE structure
# If the parameter here is zero, then a link to the note is output.
# If the parameter here is one, then the complete note is output,
#	except for level zero notes already available on a notes page.
# Otherwise, the complete note # information is output right here.

define do_note n here
local s r
{
  if (here >= 2) | ((here = 1) & (~n.xref)) then
    # Print the complete note information now, together with an anchor
    if n.xref then
       print "<A NAME=\"" n.xref "\">[<B>" n.xref "</B>]</A>" ;
    else
       print "<A NAME=\"" n.serial "\">[<B>" n.serial "</B>]</A>" ;
    end
    if n.refns | n.rin then
      print "<UL>" ;
      if n.refns then
         for r in n.refns do
           do_refn r 1 ;
         end
      end
      if n.rin then
         do_attr n.rin 1 ;
      end
      print "</UL>" ;
    end
    if n.text then
       print_text n.text 0 ;
    end
    print "<P>" ;
    if n.sources then
      for s in n.sources do
        do_citation s 1 ;
      end
    end
  else
    # Make a link to the note, either on this page, or on a notes page
    if n.xref then
       if here = 0 then
         print "<A HREF=\"" n.url "\">[" n.xref "]</A>" ;
       end
    else
       print "<A HREF=\"#" n.serial "\">[" n.serial "]</A>" ;
    end
  end
}

# Routine to output a "text" structure, which is a common
# component of several other GEDCOM structures.
# If "item" is nonzero, then an HTML <LI> is output,
# together with the GEDCOM tag associated with the text.

define print_text t item
{
  if item then
    print "<LI><EM> " t.tagname.upper "</EM>: " ;
  end
  while t do
    print t.text ;
    if t.cont then
       if CONT_MEANS_BREAK then
          print "<BR>" ;
       end
       set t to t.cont
    else
       set t to t.conc
    end
  end
}

#---------------------------------------------------------------------
# GENDEX FILE
#---------------------------------------------------------------------

# Output a "gendex.txt" index file for use by the GENDEX index
#   server at http://www.gendex.com/gendex/
#
#   Parameter i is head of a list of individuals to be output
#   in a single page.
#
# PLEASE DO NOT CHANGE THIS.  THE GENDEX SERVER DEPENDS ON THIS
#   FILE BEING IN A SPECIFIC FORMAT.

define do_gendex_ i
local e d p
{
   print ";; " VERSION ", " TODAY ;
   print ";; See the documentation to find out how this file can" ;
   print ";; be used to add your names to a master index." ;
   print ";;" ;
   while i do
     if ~i.living then
        indiv_url i ;
        print "|" ,
        if i.name & i.name.surname then
          print i.name.surname ,
        end
        print "|" ,
        if i.name & i.name.gedcom then
          print i.name.gedcom ,
        end
        print "|" ,
        set d to ""
        set p to ""
        if i.birth then
          if i.birth.date then
            set d to i.birth.date.string
          end
          if i.birth.place then
            set p to i.birth.place.name
          end
        else
          for e in i.events do
            if e.tagcode = "CHR" then
              if e.date then
                set d to e.date.string
              end
              if e.place then
                set p to e.place.name
              end
            end
          end
        end
        if d then print d , end
        print "|" ,
        if p then print p , end
        print "|" ,
        set d to ""
        set p to ""
        if i.death then
          if i.death.date then
            set d to i.death.date.string
          end
          if i.death.place then
            set p to i.death.place.name
          end
        else
          for e in i.events do
            if e.tagcode = "BURI" then
              if e.date then
                set d to e.date.string
              end
              if e.place then
                set p to e.place.name
              end
            end
          end
        end
        if d then print d , end
        print "|" ,
        if p then print p , end
        print "|" ,
     end
     print ;
     set i to i.next
   end
   print ";; This file has not been truncated." ;
}

#---------------------------------------------------------------------
# EVENTS AND ATTRIBUTES
#---------------------------------------------------------------------

# Output an event structure
#   If "item" is nonzero, then an HTML <LI> is output,
#   together with the GEDCOM tag associated with the event.

define do_event e item
{
  if item then
    print "<LI><EM>" e.tagname.upper "</EM>: " ,
  end
  if e.text then
     print e.text "<BR>" ;
  end
  do_event_detail e ;
}

# Output an attribute consisting of a single text line,
#   plus possibly an event detail.
#   If "item" is nonzero, then an HTML <LI> is output,
#   together with the GEDCOM tag associated with the attribute.

define do_attr a item
{
  if item then
    print "<LI><EM>" a.tagname.upper "</EM>: " ,
  end
  if a.text then
	print a.text "<BR>" ;
  end
  if a.event then
	do_event_detail a.event ;
  end
}

# Outting an event, except for the tag
#   This code is also used by do_attr

define do_event_detail e
local s n
{
  if e.type then
    print e.type ": " ;
  end
  if e.date & e.place then
    print e.date.value ", " e.place.name ;
  elseif e.date then
    print e.date.value ;
  elseif e.place then
    print e.place.name ;
  else
    print ;
  end
  if e.sources then
    for s in e.sources do
      do_citation s INLINE_SOURCES ;
    end
  end
  if e.notes then
    for n in e.notes do
      do_note n INLINE_NOTES ;
    end
  end
}

# Outpu a REFN structure.
#   If "item" is nonzero, then an HTML <LI> is output,
#   together with the GEDCOM tag associated with the refn.

define do_refn r item
{
  if item then
    print "<LI><EM>" r.tagname.upper ,
    if r.type then
      print " (" r.type ")" ,
    end
    print "</EM>: " ,
  end
  print r.number ;
}

# Output LDS ordinance information.
#   If "item" is nonzero, then an HTML <LI> is output,
#   together with the GEDCOM tag associated with the ordinance.

define do_ordn o item
local s
{
  if item then
    print "<LI><EM>" o.tagname.upper "</EM>: " ,
  end
  if o.date & o.place then
    print o.date.value ", " o.place.name ;
  elseif o.date then
    print o.date.value ;
  elseif o.place then
    print o.place.name ;
  else
    print ;
  end
  if o.sources then
    for s in o.sources do
      do_citation s 1 ;
    end
  end
  if o.temple then
    print "<BR><EM>" ,
    print_alternatives TEMPLE_TEXT "Temple" ;
    print "</EM>"
    print_alternatives COLON_TEXT ": " ;
    print o.temple ;
  end
  if o.status then
    print "<BR><EM>" ,
    print_alternatives STATUS_TEXT "Status" ;
    print "</EM>" ,
    print_alternatives COLON_TEXT ": " ;
    print o.status ;
  end
}

#---------------------------------------------------------------------
# INTERNATIONALIZATION
#---------------------------------------------------------------------

# Sets the value of each piece of text in the template, based on the
# specified language name.  As this gets run *after* initializations
# from any options file, we have to check each variable to see if it
# has already been given a value.
#
# The English translations are already coded as defaults in the
# rest of the template, so they don't appear again here.

define internationalize
local LANG
{
  set LANG to LANGUAGE.upper
  if LANG = "FRENCH" then
    if ~HOME_TEXT then
      set HOME_TEXT to "PAGE D'ACCUEIL"
    end
    if ~EMAIL_TEXT then
       set EMAIL_TEXT to "COURRIER"
    end
    if ~CREATED_BY_TEXT then
       set CREATED_BY_TEXT to "HTML créé par"
    end
    if ~ON_TEXT then
       set ON_TEXT to "le"
    end
    if ~AUTHOR_TEXT then
       set AUTHOR_TEXT to "Auteur"
    end
    if ~INDEX_OF_PERSONS_TEXT then
       set INDEX_OF_PERSONS_TEXT to "Index des Personnes"
    end
    if ~INDEX_OF_SURNAMES_TEXT then
       set INDEX_OF_SURNAMES_TEXT to "Index des Noms de Famille"
    end
    if ~INDIVIDUALS_TEXT then
       set INDIVIDUALS_TEXT to "personnes"
    end
    if ~FAMILIES_TEXT then
       set FAMILIES_TEXT to "familles"
    end
    if ~FROM_FILE_TEXT then
       set FROM_FILE_TEXT to "du fichier"
    end
    if ~SURNAMES_TEXT then
       set SURNAMES_TEXT to "NOMS DE FAMILLE"
    end
    if ~INDEX_TEXT then
       set INDEX_TEXT to "PERSONNES"
    end
    if ~NOTES_TEXT then
        set NOTES_TEXT to "Notes"
    end
    if ~SOURCES_TEXT then
        set SOURCES_TEXT to "Sources"
    end
    if ~UP_TEXT then
       set UP_TEXT to "PLUS HAUT"
    end
    if ~BACK_TEXT then
       set BACK_TEXT to "PRÉCÉDENT"
    end
    if ~NEXT_TEXT then
       set NEXT_TEXT to "SUIVANT"
    end
    if ~MOTHER_TEXT then
       set MOTHER_TEXT to "Mère"
    end
    if ~FATHER_TEXT then
       set FATHER_TEXT to "Père"
    end
    if ~CHILDREN_TEXT then
       set CHILDREN_TEXT to "ENFANTS"
    end
    if ~FAMILY_TEXT then
       set FAMILY_TEXT to "Famille"
    end
    if ~TEMPLE_TEXT then
       set TEMPLE_TEXT to "Temple"
    end
    if ~STATUS_TEXT then
       set STATUS_TEXT to "Status"
    end
    if ~HUSBAND_TEXT then
       set HUSBAND_TEXT to "Époux"
    end
    if ~WIFE_TEXT then
       set WIFE_TEXT to "Épouse"
    end
    if ~NAME_TEXT then
       set NAME_TEXT to "Nom"
    end
    if ~BORN_TEXT then
       set BORN_TEXT to "Naissance"
    end
    if ~AT_TEXT then
        set AT_TEXT to "à"
    end
    if ~DIED_TEXT then
        set DIED_TEXT to "Décès"
    end
    if ~MARRIED_TEXT then
        set MARRIED_TEXT to "Mariés"
    end
    if ~SPOUSES_TEXT then
        set SPOUSES_TEXT to "Conjoint(e)"
    end
    if ~COLON_TEXT then
         set COLON_TEXT to " : "
    end
  elseif LANG = "DUTCH" then
    if ~HOME_TEXT then
      set HOME_TEXT to "HOME"
    end
    if ~EMAIL_TEXT then
       set EMAIL_TEXT to "E-MAIL"
    end
    if ~CREATED_BY_TEXT then
       set CREATED_BY_TEXT to "HTML aangemaakt met"
    end
    if ~ON_TEXT then
       set ON_TEXT to "op"
    end
    if ~AUTHOR_TEXT then
       set AUTHOR_TEXT to "Auteur"
    end
    if ~INDEX_OF_PERSONS_TEXT then
       set INDEX_OF_PERSONS_TEXT to "Lijst van personen"
    end
    if ~INDEX_OF_SURNAMES_TEXT then
       set INDEX_OF_SURNAMES_TEXT to "Lijst van achternamen"
    end
    if ~INDIVIDUALS_TEXT then
       set INDIVIDUALS_TEXT to "personen"
    end
    if ~FAMILIES_TEXT then
       set FAMILIES_TEXT to "gezinnen"
    end
    if ~FROM_FILE_TEXT then
       set FROM_FILE_TEXT to "uit bestand"
    end
    if ~SURNAMES_TEXT then
       set SURNAMES_TEXT to "ACHTERNAMEN"
    end
    if ~INDEX_TEXT then
       set INDEX_TEXT to "PERSONEN"
    end
    if ~NOTES_TEXT then
        set NOTES_TEXT to "Aantekeningen"
    end
    if ~SOURCES_TEXT then
        set SOURCES_TEXT to "Bronnen"
    end
    if ~UP_TEXT then
       set UP_TEXT to "OMHOOG"
    end
    if ~BACK_TEXT then
       set BACK_TEXT to "VORIGE"
    end
    if ~NEXT_TEXT then
       set NEXT_TEXT to "VOLGENDE"
    end
    if ~MOTHER_TEXT then
       set MOTHER_TEXT to "Moeder"
    end
    if ~FATHER_TEXT then
       set FATHER_TEXT to "Vader"
    end
    if ~CHILDREN_TEXT then
       set CHILDREN_TEXT to "Kinderen"
    end
    if ~FAMILY_TEXT then
       set FAMILY_TEXT to "Gezin"
    end
    if ~TEMPLE_TEXT then
       set TEMPLE_TEXT to "Tempel"
    end
    if ~STATUS_TEXT then
       set STATUS_TEXT to "Status"
    end
    if ~HUSBAND_TEXT then
       set HUSBAND_TEXT to "Echtgenoot"
    end
    if ~WIFE_TEXT then
       set WIFE_TEXT to "Echtgenote"
    end
    if ~NAME_TEXT then
       set NAME_TEXT to "Naam"
    end
    if ~BORN_TEXT then
       set BORN_TEXT to "Geboorte"
    end
    if ~AT_TEXT then
       set AT_TEXT to ", "
    end
    if ~DIED_TEXT then
        set DIED_TEXT to "Overlijden"
    end
    if ~MARRIED_TEXT then
        set MARRIED_TEXT to "Huwelijk"
    end
    if ~SPOUSES_TEXT then
        set SPOUSES_TEXT to "Echtgenoot"
    end
    if ~COLON_TEXT then
         set COLON_TEXT to ": "
    end
  elseif LANG = "GERMAN" then
    if ~HOME_TEXT then
      set HOME_TEXT to "HOME"
    end
    if ~EMAIL_TEXT then
       set EMAIL_TEXT to "EMAIL"
    end
    if ~CREATED_BY_TEXT then
       set CREATED_BY_TEXT to "HTML erzeugt von"
    end
    if ~ON_TEXT then
       set ON_TEXT to "am"
    end
    if ~AUTHOR_TEXT then
       set AUTHOR_TEXT to "Autor"
    end
    if ~INDEX_OF_PERSONS_TEXT then
       set INDEX_OF_PERSONS_TEXT to "Index der Personen"
    end
    if ~INDEX_OF_SURNAMES_TEXT then
       set INDEX_OF_SURNAMES_TEXT to "Index der Familiennamen"
    end
    if ~INDIVIDUALS_TEXT then
       set INDIVIDUALS_TEXT to "Personen"
    end
    if ~FAMILIES_TEXT then
       set FAMILIES_TEXT to "Familien"
    end
    if ~FROM_FILE_TEXT then
       set FROM_FILE_TEXT to "aus der Datei"
    end
    if ~SURNAMES_TEXT then
       set SURNAMES_TEXT to "FAMILIENNAMEN"
    end
    if ~INDEX_TEXT then
       set INDEX_TEXT to "PERSONEN"
    end
    if ~NOTES_TEXT then
        set NOTES_TEXT to "Anmerkungen"
    end
    if ~SOURCES_TEXT then
        set SOURCES_TEXT to "Quellen"
    end
    if ~UP_TEXT then
       set UP_TEXT to "NACH OBEN"
    end
    if ~BACK_TEXT then
       set BACK_TEXT to "VORHERIGE"
    end
    if ~NEXT_TEXT then
       set NEXT_TEXT to "FOLGENDE"
    end
    if ~MOTHER_TEXT then
       set MOTHER_TEXT to "Mutter"
    end
    if ~FATHER_TEXT then
       set FATHER_TEXT to "Vater"
    end
    if ~CHILDREN_TEXT then
       set CHILDREN_TEXT to "Kinder"
    end
    if ~FAMILY_TEXT then
       set FAMILY_TEXT to "Familie"
    end
    if ~TEMPLE_TEXT then
       set TEMPLE_TEXT to "Tempel"
    end
    if ~STATUS_TEXT then
       set STATUS_TEXT to "Status"
    end
    if ~HUSBAND_TEXT then
       set HUSBAND_TEXT to "Ehemann"
    end
    if ~WIFE_TEXT then
       set WIFE_TEXT to "Ehefrau"
    end
    if ~NAME_TEXT then
       set NAME_TEXT to "Name"
    end
    if ~BORN_TEXT then
       set BORN_TEXT to "Geburt"
    end
    if ~AT_TEXT then
        set AT_TEXT to "in"
    end
    if ~DIED_TEXT then
        set DIED_TEXT to "Tod"
    end
    if ~MARRIED_TEXT then
        set MARRIED_TEXT to "Geheiratet"
    end
    if ~SPOUSES_TEXT then
        set SPOUSES_TEXT to "Ehegatte"
    end
    if ~COLON_TEXT then
         set COLON_TEXT to ": "
    end
  elseif LANG = "NORWEGIAN" then
    if ~HOME_TEXT then
      set HOME_TEXT to "HJEMMESIDE"
    end
    if ~EMAIL_TEXT then
       set EMAIL_TEXT to "E-MAIL"
    end
    if ~CREATED_BY_TEXT then
       set CREATED_BY_TEXT to "HTML opprettet av"
    end
    if ~ON_TEXT then
       set ON_TEXT to "den"
    end
    if ~AUTHOR_TEXT then
       set AUTHOR_TEXT to "Forfatter"
    end
    if ~INDEX_OF_PERSONS_TEXT then
       set INDEX_OF_PERSONS_TEXT to "Index på personer"
    end
    if ~INDEX_OF_SURNAMES_TEXT then
       set INDEX_OF_SURNAMES_TEXT to "Index på familie"
    end
    if ~INDIVIDUALS_TEXT then
       set INDIVIDUALS_TEXT to "personer"
    end
    if ~FAMILIES_TEXT then
       set FAMILIES_TEXT to "familier"
    end
    if ~FROM_FILE_TEXT then
       set FROM_FILE_TEXT to "fra filen"
    end
    if ~SURNAMES_TEXT then
       set SURNAMES_TEXT to "FAMILIER"
    end
    if ~INDEX_TEXT then
       set INDEX_TEXT to "PERSONER"
    end
    if ~NOTES_TEXT then
        set NOTES_TEXT to "Notater"
    end
    if ~SOURCES_TEXT then
        set SOURCES_TEXT to "Sources"
    end
    if ~UP_TEXT then
       set UP_TEXT to "OPP"
    end
    if ~BACK_TEXT then
       set BACK_TEXT to "TILBAKE"
    end
    if ~NEXT_TEXT then
       set NEXT_TEXT to "NESTE"
    end
    if ~MOTHER_TEXT then
       set MOTHER_TEXT to "Mor"
    end
    if ~FATHER_TEXT then
       set FATHER_TEXT to "Far"
    end
    if ~CHILDREN_TEXT then
       set CHILDREN_TEXT to "Barn"
    end
    if ~FAMILY_TEXT then
       set FAMILY_TEXT to "Familie"
    end
    if ~TEMPLE_TEXT then
       set TEMPLE_TEXT to "Tempel"
    end
    if ~STATUS_TEXT then
       set STATUS_TEXT to "Status"
    end
    if ~HUSBAND_TEXT then
       set HUSBAND_TEXT to "Ektemann"
    end
    if ~WIFE_TEXT then
       set WIFE_TEXT to "Hustru"
    end
    if ~NAME_TEXT then
       set NAME_TEXT to "Navn"
    end
    if ~BORN_TEXT then
       set BORN_TEXT to "Født"
    end
    if ~AT_TEXT then
        set AT_TEXT to ", "
    end
    if ~DIED_TEXT then
        set DIED_TEXT to "Død"
    end
    if ~MARRIED_TEXT then
        set MARRIED_TEXT to "Gift"
    end
    if ~SPOUSES_TEXT then
        set SPOUSES_TEXT to "Ektefelle"
    end
    if ~COLON_TEXT then
         set COLON_TEXT to ": "
    end
  elseif LANG = "ITALIAN" then
    if ~HOME_TEXT then
      set HOME_TEXT to "HOME"
    end
    if ~EMAIL_TEXT then
       set EMAIL_TEXT to "EMAIL"
    end
    if ~CREATED_BY_TEXT then
       set CREATED_BY_TEXT to "HTML creato da"
    end
    if ~ON_TEXT then
       set ON_TEXT to "il"
    end
    if ~AUTHOR_TEXT then
       set AUTHOR_TEXT to "Autore"
    end
    if ~INDEX_OF_PERSONS_TEXT then
       set INDEX_OF_PERSONS_TEXT to "Indice delle Persone"
    end
    if ~INDEX_OF_SURNAMES_TEXT then
       set INDEX_OF_SURNAMES_TEXT to "Indice dei Cognomi"
    end
    if ~INDIVIDUALS_TEXT then
       set INDIVIDUALS_TEXT to "individui"
    end
    if ~FAMILIES_TEXT then
       set FAMILIES_TEXT to "famiglie"
    end
    if ~FROM_FILE_TEXT then
       set FROM_FILE_TEXT to "dal file"
    end
    if ~SURNAMES_TEXT then
       set SURNAMES_TEXT to "COGNOMI"
    end
    if ~INDEX_TEXT then
       set INDEX_TEXT to "PERSONE"
    end
    if ~NOTES_TEXT then
        set NOTES_TEXT to "Note"
    end
    if ~SOURCES_TEXT then
        set SOURCES_TEXT to "Sorgenti"
    end
    if ~UP_TEXT then
       set UP_TEXT to "SOPRA"
    end
    if ~BACK_TEXT then
       set BACK_TEXT to "PRECEDENTE"
    end
    if ~NEXT_TEXT then
       set NEXT_TEXT to "SEGUENTE"
    end
    if ~MOTHER_TEXT then
       set MOTHER_TEXT to "Madre"
    end
    if ~FATHER_TEXT then
       set FATHER_TEXT to "Padre"
    end
    if ~CHILDREN_TEXT then
       set CHILDREN_TEXT to "Figli"
    end
    if ~FAMILY_TEXT then
       set FAMILY_TEXT to "Famiglia"
    end
    if ~TEMPLE_TEXT then
       set TEMPLE_TEXT to "Tempio"
    end
    if ~STATUS_TEXT then
       set STATUS_TEXT to "Stato"
    end
    if ~HUSBAND_TEXT then
       set HUSBAND_TEXT to "Sposo"
    end
    if ~WIFE_TEXT then
       set WIFE_TEXT to "Sposa"
    end
    if ~NAME_TEXT then
       set NAME_TEXT to "Nome"
    end
    if ~BORN_TEXT then
       set BORN_TEXT to "Nascita"
    end
    if ~AT_TEXT then
        set AT_TEXT to "a"
    end
    if ~DIED_TEXT then
        set DIED_TEXT to "Morte"
    end
    if ~MARRIED_TEXT then
        set MARRIED_TEXT to "sposato"
    end
    if ~SPOUSES_TEXT then
        set SPOUSES_TEXT to "Coniuge"
    end
    if ~COLON_TEXT then
         set COLON_TEXT to " : "
    end
  elseif LANG = "SWEDISH" then
    if ~HOME_TEXT then
      set HOME_TEXT to "HEMSIDE"
    end
    if ~EMAIL_TEXT then
       set EMAIL_TEXT to "E-MAIL"
    end
    if ~CREATED_BY_TEXT then
       set CREATED_BY_TEXT to "HTML skapad av"
    end
    if ~ON_TEXT then
       set ON_TEXT to ""
    end
    if ~AUTHOR_TEXT then
       set AUTHOR_TEXT to "Författare"
    end
    if ~INDEX_OF_PERSONS_TEXT then
       set INDEX_OF_PERSONS_TEXT to "Personindex"
    end
    if ~INDEX_OF_SURNAMES_TEXT then
       set INDEX_OF_SURNAMES_TEXT to "Familjeindex"
    end
    if ~INDIVIDUALS_TEXT then
       set INDIVIDUALS_TEXT to "personer"
    end
    if ~FAMILIES_TEXT then
       set FAMILIES_TEXT to "familjer"
    end
    if ~FROM_FILE_TEXT then
       set FROM_FILE_TEXT to "från filen"
    end
    if ~SURNAMES_TEXT then
       set SURNAMES_TEXT to "FAMILJER"
    end
    if ~INDEX_TEXT then
       set INDEX_TEXT to "PERSONER"
    end
    if ~NOTES_TEXT then
        set NOTES_TEXT to "Anteckningar"
    end
    if ~SOURCES_TEXT then
        set SOURCES_TEXT to "Källor"
    end
    if ~UP_TEXT then
       set UP_TEXT to "UPP"
    end
    if ~BACK_TEXT then
       set BACK_TEXT to "TILLBAKA"
    end
    if ~NEXT_TEXT then
       set NEXT_TEXT to "NÄSTA"
    end
    if ~MOTHER_TEXT then
       set MOTHER_TEXT to "Mor"
    end
    if ~FATHER_TEXT then
       set FATHER_TEXT to "Far"
    end
    if ~CHILDREN_TEXT then
       set CHILDREN_TEXT to "Barn"
    end
    if ~FAMILY_TEXT then
       set FAMILY_TEXT to "Familj"
    end
    if ~TEMPLE_TEXT then
       set TEMPLE_TEXT to "Tempel"
    end
    if ~STATUS_TEXT then
       set STATUS_TEXT to "Status"
    end
    if ~HUSBAND_TEXT then
       set HUSBAND_TEXT to "Make"
    end
    if ~WIFE_TEXT then
       set WIFE_TEXT to "Hustru"
    end
    if ~NAME_TEXT then
       set NAME_TEXT to "Namn"
    end
    if ~BORN_TEXT then
       set BORN_TEXT to "Född"
    end
    if ~AT_TEXT then
        set AT_TEXT to ", "
    end
    if ~DIED_TEXT then
        set DIED_TEXT to "Död"
    end
    if ~MARRIED_TEXT then
        set MARRIED_TEXT to "Gift"
    end
    if ~SPOUSES_TEXT then
        set SPOUSES_TEXT to "Make"
    end
    if ~COLON_TEXT then
         set COLON_TEXT to ": "
    end
  elseif LANG = "DANISH" then
    if ~HOME_TEXT then
      set HOME_TEXT to "HJEMMESIDE"
    end
    if ~EMAIL_TEXT then
       set EMAIL_TEXT to "E-POST"
    end
    if ~CREATED_BY_TEXT then
       set CREATED_BY_TEXT to "HTML dannet af"
    end
    if ~ON_TEXT then
       set ON_TEXT to "den"
    end
    if ~AUTHOR_TEXT then
       set AUTHOR_TEXT to "Forfatter"
    end
    if ~INDEX_OF_PERSONS_TEXT then
       set INDEX_OF_PERSONS_TEXT to "Personregister"
    end
    if ~INDEX_OF_SURNAMES_TEXT then
       set INDEX_OF_SURNAMES_TEXT to "Efternavnsregister"
    end
    if ~INDIVIDUALS_TEXT then
       set INDIVIDUALS_TEXT to "personer"
    end
    if ~FAMILIES_TEXT then
       set FAMILIES_TEXT to "familier"
    end
    if ~FROM_FILE_TEXT then
       set FROM_FILE_TEXT to "fra filen"
    end
    if ~SURNAMES_TEXT then
       set SURNAMES_TEXT to "EFTERNAVNE"
    end
    if ~INDEX_TEXT then
       set INDEX_TEXT to "PERSONER"
    end
    if ~NOTES_TEXT then
        set NOTES_TEXT to "Bemærkninger"
    end
    if ~SOURCES_TEXT then
        set SOURCES_TEXT to "Kilder"
    end
    if ~UP_TEXT then
       set UP_TEXT to "OP"
    end
    if ~BACK_TEXT then
       set BACK_TEXT to "TILBAGE"
    end
    if ~NEXT_TEXT then
       set NEXT_TEXT to "NÆSTE"
    end
    if ~MOTHER_TEXT then
       set MOTHER_TEXT to "Mor"
    end
    if ~FATHER_TEXT then
       set FATHER_TEXT to "Far"
    end
    if ~CHILDREN_TEXT then
       set CHILDREN_TEXT to "Børn"
    end
    if ~FAMILY_TEXT then
       set FAMILY_TEXT to "Familie"
    end
    if ~TEMPLE_TEXT then
       set TEMPLE_TEXT to "Tempel"
    end
    if ~STATUS_TEXT then
       set STATUS_TEXT to "Status"
    end
    if ~HUSBAND_TEXT then
       set HUSBAND_TEXT to "Ægtemand"
    end
    if ~WIFE_TEXT then
       set WIFE_TEXT to "Hustru"
    end
    if ~NAME_TEXT then
       set NAME_TEXT to "Navn"
    end
    if ~BORN_TEXT then
       set BORN_TEXT to "Født"
    end
    if ~AT_TEXT then
        set AT_TEXT to "i"
    end
    if ~DIED_TEXT then
        set DIED_TEXT to "Død"
    end
    if ~MARRIED_TEXT then
        set MARRIED_TEXT to "Gift"
    end
    if ~SPOUSES_TEXT then
        set SPOUSES_TEXT to "Ægtefælle"
    end
    if ~COLON_TEXT then
         set COLON_TEXT to ": "
    end
  else
    if ~HOME_TEXT then
#      set HOME_TEXT to ""
    end
    if ~EMAIL_TEXT then
#       set EMAIL_TEXT to ""
    end
    if ~CREATED_BY_TEXT then
#       set CREATED_BY_TEXT to ""
    end
    if ~ON_TEXT then
#       set ON_TEXT to ""
    end
    if ~AUTHOR_TEXT then
#       set AUTHOR_TEXT to ""
    end
    if ~INDEX_OF_PERSONS_TEXT then
#       set INDEX_OF_PERSONS_TEXT to ""
    end
    if ~INDEX_OF_SURNAMES_TEXT then
#       set INDEX_OF_SURNAMES_TEXT to ""
    end
    if ~INDIVIDUALS_TEXT then
#       set INDIVIDUALS_TEXT to ""
    end
    if ~FAMILIES_TEXT then
#       set FAMILIES_TEXT to ""
    end
    if ~FROM_FILE_TEXT then
#       set FROM_FILE_TEXT to ""
    end
    if ~SURNAMES_TEXT then
#       set SURNAMES_TEXT to ""
    end
    if ~INDEX_TEXT then
#       set INDEX_TEXT to ""
    end
    if ~NOTES_TEXT then
#        set NOTES_TEXT to ""
    end
    if ~SOURCES_TEXT then
#        set SOURCES_TEXT to ""
    end
    if ~UP_TEXT then
#       set UP_TEXT to ""
    end
    if ~BACK_TEXT then
#       set BACK_TEXT to ""
    end
    if ~NEXT_TEXT then
#       set NEXT_TEXT to ""
    end
    if ~MOTHER_TEXT then
#       set MOTHER_TEXT to ""
    end
    if ~FATHER_TEXT then
#       set FATHER_TEXT to ""
    end
    if ~CHILDREN_TEXT then
#       set CHILDREN_TEXT to ""
    end
    if ~FAMILY_TEXT then
#       set FAMILY_TEXT to ""
    end
    if ~TEMPLE_TEXT then
#       set TEMPLE_TEXT to ""
    end
    if ~STATUS_TEXT then
#       set STATUS_TEXT to ""
    end
    if ~HUSBAND_TEXT then
#       set HUSBAND_TEXT to ""
    end
    if ~WIFE_TEXT then
#       set WIFE_TEXT to ""
    end
    if ~NAME_TEXT then
#       set NAME_TEXT to ""
    end
    if ~BORN_TEXT then
#       set BORN_TEXT to ""
    end
    if ~AT_TEXT then
#        set AT_TEXT to ""
    end
    if ~DIED_TEXT then
#        set DIED_TEXT to ""
    end
    if ~MARRIED_TEXT then
#        set MARRIED_TEXT to ""
    end
    if ~SPOUSES_TEXT then
#        set SPOUSES_TEXT to ""
    end
    if ~COLON_TEXT then
#         set COLON_TEXT to ": "
    end
  end
}


#
# Fixed format pedigree code by David Stafford <dstafford@i-f.com>
# (modified by Gene Stark for GED2HTML v3.5)
#
# He said (on April 7, 1998):
# Here is the code which works fine on my data set you may want to check it
# out yourself.
# There is just one point worth noting:  if the individual being process does
# not have a linked father - the code assumes that individual doesn't have a
# paternal grandparents either.  The same goes for the mother's side.
# Obviously this causes a problem when one has information about a grandparent
# and a grandchild but not about the parent.  In my experience, that is a rare
# occurance, but I guess it may be a restriction for some people.
#
#Please feel free to use this code as you see fit.

define pedigree_out i 
local m p purl myf myfn myfu
      mym mymn mymu
      myff myffn myffu 
      myfm myfmn myfmu
      mymf mymfn mymfu
      mymm mymmn mymmu
      myfff myfffn myfffu
      myffm myffmn myffmu
      myfmf myfmfn myfmfu
      myfmm myfmmn myfmmu
      mymff mymffn mymffu
      mymfm mymfmn mymfmu
      mymmf mymmfn mymmfu
      mymmm mymmmn mymmmu
{
   if i.father then
        set myf to i.father
        set myfn to i.father.name.fullname
#      set myfu to i.father.url

    set p to myf
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set myfu to purl


        if myf.father then

    set p to myf.father
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set myffu to purl

#                set myffu to myf.father.url
                set myffn to myf.father.name.fullname
                set myff to myf.father
                if myff.father then
                        set myfffn to myff.father.name.fullname
#                        set myfffu to myff.father.url

    set p to myff.father
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set myfffu to purl



                else                       
                        set myfffn to "Not Known"
                end
                if myff.mother then
                        set myffmn to myff.mother.name.fullname
#                        set myffmu to myff.mother.url

    set p to myff.mother
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set myffmu to purl


                else
                        set myffmn to "Not Known"
                end
        else
                set myffn to "Not Known"
                set myffmn to "Not Known"
                set myfffn to "Not Known"
        end
        if myf.mother then
                set myfm to myf.mother
                set myfmn to myf.mother.name.fullname
#                set myfmu to myf.mother.url

    set p to myf.mother
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set myfmu to purl


                if myfm.father then
                        set myfmfn to myfm.father.name.fullname
#                        set myfmfu to myfm.father.url

    set p to myfm.father
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set myfmfu to purl


                else
                        set myfmfn to "Not Known" 
                end
                if myfm.mother then
                        set myfmm to myfm.mother
                        set myfmmn to myfm.mother.name.fullname
#                        set myfmmu to myfm.mother.url

    set p to myfm.mother
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set myfmmu to purl

                else
                        set myfmmn to "Not Known" 
                end
        else
                set myfmn to "Not Known"
                set myfmfn to "Not Known"
                set myfmmn to "Not Known"
        end
  else
        set myfffn to "Not Known"
        set myffmn to "Not Known"
        set myffn to "Not Known"
        set myfmn to "Not Known"
        set myfmfn to "Not Known"
        set myfmmn to "Not Known"
        set myfn to "Not Known"
  end

  if i.mother then
        set mym to i.mother
        set mymn to i.mother.name.fullname
#        set mymu to i.mother.url


    set p to i.mother
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set mymu to purl

        if mym.father then
#                set mymfu to mym.father.url

    set p to mym.father
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set mymfu to purl

                set mymfn to mym.father.name.fullname
                set mymf to mym.father
                if mymf.father then
                        set mymffn to mymf.father.name.fullname
#                        set mymffu to mymf.father.url

    set p to mymf.father
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set mymffu to purl


                else                       
                        set mymffn to "Not Known"
                end
                if mymf.mother then
                        set mymfmn to mymf.mother.name.fullname
#                        set mymfmu to mymf.mother.url

    set p to mymf.mother
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set mymfmu to purl

                else
                        set mymfmn to "Not Known"
                end
        else
                set mymfn to "Not Known"
                set mymfmn to "Not Known"
                set mymffn to "Not Known"
        end
        if mym.mother then
                set mymm to mym.mother
                set mymmn to mym.mother.name.fullname
#                set mymmu to mym.mother.url

    set p to mym.mother
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set mymmu to purl

                if mymm.father then
                        set mymmfn to mymm.father.name.fullname
#                        set mymmfu to mymm.father.url

    set p to mymm.father
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set mymmfu to purl

                else
                        set mymmfn to "Not Known" 
                end
                if mymm.mother then
                        set mymmm to mymm.mother
                        set mymmmn to mymm.mother.name.fullname
#                        set mymmmu to mymm.mother.url

    set p to mymm.mother
    if p.marriages then
      set m to p.marriages
      if m then
         set purl to m.url  ^ "#" ^ p.xref
      end
    else
      set m to p.families
      if m then
        set purl to m.url  ^ "#" ^ p.xref
      else
        set m to p.url
      end
    end
    set mymmmu to purl

                else
                        set mymmmn to "Not Known" 
                end
        else
                set mymmn to "Not Known"
                set mymmfn to "Not Known"
                set mymmmn to "Not Known"
        end
  else
        set mymffn to "Not Known"
        set mymfmn to "Not Known"
        set mymfn to "Not Known"
        set mymmn to "Not Known"
        set mymmfn to "Not Known"
        set mymmmn to "Not Known"
        set mymn to "Not Known"
  end
  print "<PRE>" ;
  if myfffn = "Not Known" then
        print "      /--";
  else
        print "      /--<a href=\"" myfffu "\">"myfffn"</a>";
  end
  if myffn = "Not Known" then
        print "   /--";
  else
        print "   /--<a href=\"" myffu "\">"myffn"</a>";
  end
  if myffmn = "Not Known" then
        print "   |  \--";
  else
        print "   |  \--<a href=\""myffmu "\">"myffmn"</a>";
  end
  if myfn = "Not Known" then
        print "/--";
  else
        print "/--<a href=\"" myfu "\">"myfn"</a>";
  end
  if myfmfn = "Not Known" then
        print "|  |  /--";
  else
        print "|  |  /--<a href=\"" myfmfu "\">"myfmfn"</a>";
  end
  if myfmn = "Not Known" then
        print "|  \--";
  else
        print "|  \--<a href=\"" myfmu "\">"myfmn"</a>";
  end
  if myfmmn = "Not Known" then
        print "|     \--";
  else
        print "|     \--<a href=\"" myfmmu "\">"myfmmn"</a>";
  end
  print "|--"i.name.fullname;
  if mymffn = "Not Known" then
        print "|     /--";
  else
        print "|     /--<a href=\"" mymffu "\">"mymffn"</a>";
  end
  if mymfn = "Not Known" then
        print "|  /--";
  else
        print "|  /--<a href=\"" mymfu "\">"mymfn"</a>";
  end
  if mymfmn = "Not Known" then
        print "|  |  \--";
  else
        print "|  |  \--<a href=\"" mymfmu "\">"mymfmn"</a>";
  end
  if mymn = "Not Known" then
        print "\--";
  else
        print "\--<a href=\"" mymu "\">"mymn"</a>";
  end
  if mymffn = "Not Known" then
         print "   |  /--";
  else
         print "   |  /--<a href=\"" mymffu "\">"mymffn"</a>";
  end
  if mymmn = "Not Known" then
        print "   \--";
  else
        print "   \--<a href=\"" mymmu "\">"mymmn"</a>";
  end
  if mymmmn = "Not Known" then
        print "      \--";
  else
        print "      \--<a href=\"" mymmmu "\">"mymmmn"</a>";
  end
  print "</pre><br>";
}